Estrellas y banderas

En esta sección vas a aprender a dibujar una estrella de varias puntas y a dibujar las banderas gallega, española y europea. Intenta hacer los dibujos tú mismo. Algunos son un poco difíciles, así que si no te salen puedes ver la solución.

Para hacer una estrella de 5 puntas primero es necesario que primero recuerdes cómo se hacía un pentágono (Ver solución 1)

¿Qué ocurriría si utilizamos "puntas de estrella" en lugar de líneas rectas para dibujar cada uno de los lados del pentágono?

Punta de estrella:

 lt 75 fd 100 rt 150 fd 100 lt 75

Estrella de 5 puntas:

to estrella5
repeat 5 [
 lt 75 fd 100 rt 150 fd 100 lt 75 
 rt 360/5 
]
end

Estrella de 5 puntas pequeña rellena con amarillo:

to estrella5
repeat 5 [
 lt 75 fd 20 rt 150 fd 20 lt 75
 rt 360/5 
]
setfloodcolor [ 255 255 0 ]
pu fd 5 fill bk 5 pd
end

Ahora la bandera europea no es más que colocar 15 estrellas en los vértices de un polígono de 15 lados (Ver solución 2) y rellenar de azul:

¿Sabrías hacer la bandera española? (Ver solución 3)

¿Y la bandera gallega? (Ver solución 4)

Soluciones

```
  repeat 5 [ fd 100 rt 360/5 ]
  
```

to euro
repeat 15 [
 estrella5
 pu fd 50 rt 360/15 pd
]
pu
rt 90 fd 30
setfloodcolor [ 0 0 128 ]
fill
bk 30 lt 90
pd
end

to gallega
repeat 2 [
 fd 80 rt 113.96 fd 196.98 bk 196.98 lt 113.96
 fd 20 rt 90 fd 200 rt 90 
]
pu 
fd 50 rt 90 fd 100
setfloodcolor [ 0 128 255 ]
fill
bk 100 lt 90 bk 50
pd
end

to espanhola
repeat 2 [
 fd 100 rt 90 fd 200 rt 90
]
repeat 2 [
 fd 33 rt 90 fd 200 bk 200 lt 90
]
 bk 66
 pu 
 fd 23 rt 90 fd 10 lt 90
 setfloodcolor [ 255 0 0 ] fill
 fd 33
 setfloodcolor [ 255 255 0 ] fill
 fd 33
 setfloodcolor [ 255 0 0 ] fill
 bk 89 lt 90 fd 10 rt 90
 pd
End